/**
Cube Monster by Eduardo Omine [2008-11-16]
http://blog.omine.net/
*/

class Monster
{
	int NUM_CUBES = 50;
	int NUM_RADIUS = 8;
	float KNUM_RADIUS = TWO_PI / NUM_RADIUS;
	float FLAP = HALF_PI * 0.6;
	float ref, perlin, faceX, eye, eyeA, mouth, flap;
	Vec2 delta, rot, vel, pos;
	boolean angry;
	int nextCube;
	Cube[] cubes;
	
	Monster()
	{
		delta		= new Vec2();
		rot			= new Vec2();
		vel			= new Vec2();
		pos			= new Vec2(200, 200);
		nextCube	= 0;
		cubes		= new Cube[NUM_CUBES];
		for(int i=0; i<NUM_CUBES; i++) cubes[i] = new Cube();
	}
	
	void update()
	{
		ref		= frameCount * 0.2;
		delta.set(mouseX-pos.x, mouseY-30-pos.y);
		rot.set(radians(delta.y)*-0.25, radians(delta.x)*0.1);
		vel.set(delta);
		vel.mult(0.05);
		pos.add(vel.x, vel.y+cos(ref)*0.5);
		pos.bound(0, 0, 400, 400);
		
		perlin	= noise(ref);
		faceX	= delta.x * 0.05;
		eye		= 10 - perlin * 5;
		eyeA	= (angry) ? PI * 0.35 : 0;
		mouth	= 10 + perlin * 10;
		flap	= (sin(ref) * 0.5 + 0.5) * FLAP;
		
		if(angry)
		{
			mouth *= 0.5;
			pos.addRand(-2,2);
			if(frameCount % 2 == 0) shootAngry();
		}
		else
		{
			if(frameCount % 25 == 0) shootCalm();
		}
		
		for(int i=0; i<NUM_CUBES; i++) cubes[i].update();
	}
	
	void draw()
	{
		pushMatrix();
		translate(pos.x, pos.y, 0);
		rotateX(rot.x);
		rotateY(rot.y);
		rotateZ(rot.y);
		fill(255);
		stroke(0);
		drawBox(-12+faceX, -10, 22, eye, 12, 5, -eyeA); // left eye
		drawBox( 12+faceX, -10, 22, eye, 12, 5,  eyeA); // right eye
		drawBox(faceX, 10, 22, 30, mouth, 5); // mouth
		fill(0);
		stroke(255);
		box(50, 50, 40); // body
		drawBox(-25, 0, 0, 30, 8, 35, -flap); // left wing
		drawBox( 25, 0, 0, 30, 8, 35,  flap); // right wing
		popMatrix();
		for(int i=0; i<NUM_CUBES; i++) cubes[i].draw();
	}
	
	void toggleAngry()
	{
		angry = !angry;
	}
	
	void shootAngry()
	{
		cubes[nextCube].reset(pos);
		findNextCube();
	}
	
	void shootCalm()
	{
		for(int i=0; i<NUM_RADIUS; i++)
		{
			cubes[nextCube].reset(pos, radians(frameCount*4)+i*KNUM_RADIUS);
			findNextCube();
		}
	}
	
	void findNextCube()
	{
		for(int i=1; i<NUM_CUBES; i++)
		{
			int j = nextCube + i;
			if(j >= NUM_CUBES) j = j - NUM_CUBES;
			if(cubes[j].dead)
			{
				nextCube = j;
				break;
			}
		}
	}
}